Това изображение (или всички изображения в тази страница/категория) би трябвало да бъдат пресъздадени с използване на векторна графика във формат SVG. Това има няколко предимства; вижте Commons:Media for cleanup за повече информация. Ако разполагате с това избражение в SVG формат, моля качете го. След това заместете този шаблон с {{Vector version available|име на новия файл.svg}}.

A triangle with incircle, contact triangle and Gergonne point. Released into the public domain by Axel Boldt. Created with GCLC using the following input:

% The three vertices of the triangle
point A 15 80
point B 13 30
point C 45 60

% They define three lines
line a B C
line b A C
line c A B

% The three internal angle bisectors
bis bis_A B A C
bis bis_B A B C
bis bis_C B C A

% The center of the incircle
intersec incenter bis_A bis_B

% The points where the incircle
% touches the triangle.
perp dummy_line incenter a
intersec T_A dummy_line a
perp dummy_line incenter b
intersec T_B dummy_line b
perp dummy_line incenter c
intersec T_C dummy_line c

% The incircle
circle incircle incenter T_A

% Gergonne point 
line AT_A A T_A
line BT_B B T_B
intersec G AT_A BT_B

% Now draw everything
dim 70 100

color 0 200 0
drawsegment A T_A
drawsegment B T_B
drawsegment C T_C

mark_t G

color 255 0 0
drawsegment T_A T_B
drawsegment T_B T_C
drawsegment T_C T_A

%Kludge to print indices T_A, T_B and T_C...
point P1 1 1
point P2 2 0

printat_rb T_A {T}
translate T_A1 P1 P2 T_A
printat_rb T_A1 {A}

printat_rt T_B {T}
translate T_B1 P1 P2 T_B
printat_rt T_B1 {B}

printat_l T_C {T }
translate T_C1 P1 P2 T_C 
printat_l T_C1 {C }

color 0 0 0

drawcircle incircle

drawsegment A B
drawsegment B C
drawsegment C A

mark_t A
mark_lb B
mark_r C

Тази творба е публикувана от своя автор, AxelBoldt, като обществено достояние. Това разрешение е в сила за целия свят. В някои държави това може да не е възможно от законодателна гледна точка; затова: AxelBoldt дава на всекиго правото да използва тази творба за всякакви цели, без никакви условия, освен ако такива условия съществуват по закон.