Това изображение (или всички изображения в тази страница/категория) би трябвало да бъдат пресъздадени с използване на векторна графика във формат SVG. Това има няколко предимства; вижте Commons:Media for cleanup за повече информация. Ако разполагате с това избражение в SVG формат, моля качете го. След това заместете този шаблон с {{Vector version available|име на новия файл.svg}}.

Резюме

Качествени изображения Това изображение е оценено съобразно ръководството за качествени изображения и се счита за качествено изображение. العربية ∙ جازايرية ∙ беларуская ∙ беларуская (тарашкевіца) ∙ български ∙ বাংলা ∙ català ∙ čeština ∙ Cymraeg ∙ Deutsch ∙ Schweizer Hochdeutsch ∙ Zazaki ∙ Ελληνικά ∙ English ∙ Esperanto ∙ español ∙ eesti ∙ euskara ∙ فارسی ∙ suomi ∙ français ∙ galego ∙ עברית ∙ हिन्दी ∙ hrvatski ∙ magyar ∙ հայերեն ∙ Bahasa Indonesia ∙ italiano ∙ 日本語 ∙ Jawa ∙ ქართული ∙ 한국어 ∙ kurdî ∙ Lëtzebuergesch ∙ lietuvių ∙ македонски ∙ മലയാളം ∙ मराठी ∙ Bahasa Melayu ∙ Nederlands ∙ Norfuk / Pitkern ∙ polski ∙ português ∙ português do Brasil ∙ rumantsch ∙ română ∙ русский ∙ sicilianu ∙ slovenčina ∙ slovenščina ∙ shqip ∙ српски / srpski ∙ svenska ∙ தமிழ் ∙ తెలుగు ∙ ไทย ∙ Tagalog ∙ Türkçe ∙ toki pona ∙ українська ∙ vèneto ∙ Tiếng Việt ∙ 中文 ∙ 中文（简体） ∙ 中文（繁體） ∙ +/−

Лицензиране

Аз, носителят на авторските права над тази творба, я публикувам тук под следните лицензи:

Предоставя се разрешение за копиране, разпространение и/или модификация на този документ според Лиценза за свободна документация на ГНУ, в своята версия 1.2 или някоя следваща версия, издадена от Фондацията за свободен софтуер; без непроменими раздели, без текст на предната подвързия и без текст на задната подвързия. Копие на този лиценз е приложено в раздела Лиценз за свободна документация на ГНУ.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Този файл се разпространява под лиценз Криейтив Комънс Признание — Споделяне на споделеното 3.0.
	Можете свободно: да споделяте – да копирате, разпространявате и излъчвате произведението да ремиксирате – да адаптирате произведението Съгласно следните условия: признание на авторството – Трябва да посочите авторството, да добавите връзка към лиценза и да посочите дали са правени промени. Можете да направите това по всякакъв разумен начин, но не и по начин, оставящ впечатлението, че същият/същите подкрепят вас или използването по някакъв начин на творбата от вас. споделяне на споделеното – В случай, че промените, видоизмените или използвайки като основа произведението, го надградите, то полученото производно произведение може да се разпространява само съгласно условията на същия или съвместим лиценз с оригиналния такъв.
	This licensing tag was added to this file as part of the GFDL licensing update.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Този файл се разпространява под лиценза Криейтив Комънс Признание - Споделяне на споделеното 2.5 Надаптиран, 2.0 Неадаптиран и 1.0 Неадаптиран.

Можете свободно:

• да споделяте – да копирате, разпространявате и излъчвате произведението
• да ремиксирате – да адаптирате произведението

Съгласно следните условия:

• признание на авторството – Трябва да посочите авторството, да добавите връзка към лиценза и да посочите дали са правени промени. Можете да направите това по всякакъв разумен начин, но не и по начин, оставящ впечатлението, че същият/същите подкрепят вас или използването по някакъв начин на творбата от вас.
• споделяне на споделеното – В случай, че промените, видоизмените или използвайки като основа произведението, го надградите, то полученото производно произведение може да се разпространява само съгласно условията на същия или съвместим лиценз с оригиналния такъв.

https://creativecommons.org/licenses/by-sa/2.5CC BY-SA 2.5 Creative Commons Attribution-Share Alike 2.5 truetrue

Можете да изберете лиценз по Ваш избор.

Made using povray 3.6 and the following code:

#declare RAD = on;   // use radiosity?
#declare Exploded=on; // exploded view or not?
#declare CoilLength = 2.6;

#include "functions.inc"
#include "metals.inc"
#include "colors.inc"
global_settings {
  #if(RAD)
    radiosity {
      brightness 0.60 
      count 100
      error_bound 0.2
      gray_threshold 0.0
      low_error_factor 0.2
      minimum_reuse 0.015
      nearest_count 10
      recursion_limit 1
      #if (version>3.1)
        adc_bailout 0.01
        max_sample -1.0
        media off
        normal off
        always_sample 1
        pretrace_start 0.08
        pretrace_end 0.01
      #end
    }
  #end
}

background { color White }

// declarations for the E magnetic core------------------------------------------------
#declare corner = intersection { // a quarter of cyclindic volume used to "round" the corners
  lathe { 
    linear_spline
    6
    <0,0>,<0.05,0>, <0.1,0.05>, <0.1,2.95>,<0.05,3>, <0,3>
    rotate 90*x 
  }
  box {<-10,-10,-10>,<10,0,10>}
}
 
#declare side =  prism { // the extrusions of the volume
  linear_sweep
  linear_spline
  0, 1, 9,
  <0.05,0>, <0,0.05>, <0,2.95>, <0.05,3>, <0.25,3>, <0.3,2.95>, <0.3,0.05>, <0.25,0>, <0.05,0>
}

#declare middle =  prism { // the extrusion of the middle leg
  linear_sweep
  linear_spline
  0, 1, 9,
  <0.05,0>, <0,0.05>, <0,2.95>, <0.05,3>, <0.95,3>, <1,2.95>, <1,0.05>, <0.95,0>, <0.05,0>
}

#declare Ecore = difference {
  union {
    object {side scale <1,3.4,1> rotate -90*z translate <-1.7,0.2,0> }
    object {side scale <1,0.5,1> translate -1.8*x  }
    object {middle scale 0.5*y translate -.5*x  }
    object {side scale <1,0.5,1> translate 1.5*x  }
    object {corner translate -1.7*x}
    object {corner translate 1.7*x}
  }
  union { // the notches where the clips sit
      box {<-10,-10,1.2>,<-1.5,0,1.8>}
      box {<10,-10,1.2>,<1.5,0,1.8>}
  }
  pigment {Gray50}
} 

// declarations for the I magnetic core------------------------------------------------
#declare Icore =  difference {
  union {
    object {side scale <1,3.4,1> rotate -90*z translate <-1.7,0.2,0> }
    object {side scale <1,0.2,1> translate -1.8*x  }
    object {middle scale 0.2*y translate -.5*x  }
    object {side scale <1,0.2,1> translate 1.5*x  }
    object {corner translate -1.7*x}
    object {corner translate 1.7*x}
  }
  union { // the notches where the clips sit
      box {<-10,-10,1.2>,<-1.5,0,1.8>}
      box {<10,-10,1.2>,<1.5,0,1.8>}
  }
  pigment {Gray50}
}

//declaration of the coil element-----------------------
#declare coil = union {
  union {
    #declare NbTurns = 8;
    #declare Pitch =0.08; // the distance between two loops
    #declare Xstart =0.6;  // the spiral rolls around the origin
    #declare Zstart =2;
    #declare InitCorner =0.4; // initial length of the 45degree filet
    #declare Index=0;
    #declare Width=0.05;
    #declare DeltaL=Pitch*tan(radians(22.5)); //variation in lenght of the track on each turn
    #while(Index <= NbTurns)
      #declare Lengthcorner=InitCorner+2*Index*DeltaL;
      #declare Xlength=2*(Xstart+Index*DeltaL-InitCorner*cos(radians(45)));
      #declare Zlength=2*(Zstart+Index*DeltaL-InitCorner*cos(radians(45)));
      box{<0,0,0>,<-Width,0.01,-Zlength> translate <Xstart+Index*Pitch,0,Zlength/2>}
      box{<0,0,0>,<-Width,0.01,-Lengthcorner> rotate 45*y translate <Xstart+Index*Pitch,0,-Zlength/2>}
      box{<0,0,0>,<-Xlength,0.01,Width> translate <Xlength/2,0,-Zstart-Index*Pitch>}
      box{<0,0,0>,<-Width,0.01,-Lengthcorner> rotate 135*y translate <-Xlength/2,0,-Zstart-Index*Pitch>}
      box{<0,0,0>,<Width,0.01,Zlength+DeltaL> translate <-Xstart-Index*Pitch,0,-Zlength/2>}
      box{<0,0,0>,<-Width,0.01,-Lengthcorner> rotate 225*y translate <-Xstart-Index*Pitch,0,Zlength/2+DeltaL>}
      box{<0,0,0>,<Xlength+Pitch,0.01,-Width> translate <-Xlength/2,0,+Zstart+Index*Pitch+DeltaL>}
      box{<0,0,0>,<-Width,0.01,-Lengthcorner> rotate 315*y translate <Xlength/2+Pitch,0,+Zstart+Index*Pitch+DeltaL>}
      #declare Index = Index + 1;
    #end
    box{<0,0,0>,<-Width,0.01,-Zlength-0.5> translate <Xstart+Index*Pitch,0,Zlength/2>}//connections to the pads
    box{<0,0,0>,<Xstart-InitCorner*cos(radians(45))/2,0.01,-Width> translate <0,0,Zstart-InitCorner*cos(radians(45))/2>} 
    box{<0,0,0>,<-Width,0.01,-InitCorner/2> rotate 315*y translate <Xstart-InitCorner*cos(radians(45))/2,0,Zstart-InitCorner*cos(radians(45))/2>}
    pigment { P_Copper4 }
  }
  cylinder{<0,0,0><0,0.015,0>,Width translate <Xstart+Index*Pitch-Width/2,0,-Zlength/2-0.5>}
  cylinder{<0,0,0><0,0.015,0>,Width translate <0,0,Zstart-InitCorner*cos(radians(45))/2-Width/2>}
  pigment { P_Copper4 }
}

//declaration of the pcb------------------------------
#declare PCB = difference {
  box {
    <-3,0,-3>,<3,0.2,3>
  }
  union {
    box {<-0.5,-10,-1.6>,<0.5,10,1.6>}
    box {<-1.9,-10,-1.6>,<-1.4,10,1.6>}
    box {<1.4,-10,-1.6>,<1.9,10,1.6>}
    box {<-2.0,-10,-0.3>,<-1.6,10,0.3>}
    box {<1.6,-10,-0.3>,<2.0,10,0.3>}
  }
  pigment{LimeGreen}
  finish{F_MetalB}
}


//declarations for the clip ---------------------------
#declare halfclip = prism {
  linear_sweep
  bezier_spline
  0, 1, 32, // the following points value come from another model, hence the fancy values
  <0,0>,<1.2,0>,<0,0>,<1.2,0>,
  <1.2,0>,<1.3,0>,<1.6,-0.2>,<1.7,-0.2>,
  <1.7,-0.2>,<1.8,-0.2>,<1.8,-0.2>,<1.8,1>,
  <1.8,1>,<1.9,1>,<1.8,1>,<1.9,1>,
  <1.9,1>,<1.9,-0.3>,<1.9,-0.3>,<1.7,-0.3>,
  <1.7,-0.3>,<1.6,-0.3>,<1.3,-0.1>,<1.2,-0.1>,
  <1.2,-0.1>,<0,-0.1>,<1.2,-0.1>,<0,-0.1>,
  <0,-0.1>,<0,0>,<0,-0.1>,<0,0>
  pigment {P_Chrome1}
  finish {F_MetalD}
}
#declare completeclip = union {
  object{halfclip scale 0.5*y}
  object{halfclip scale 0.5*y rotate 180*z translate 0.5*y} 
}

// the final union-------------------------------------------------
union {
  #if(Exploded)  
    object {coil translate <0,1.9,1.5>}
    object {PCB translate <0,1.7,1.5>}
    object {completeclip scale <0.7/3.6,1,0.7/3.6> rotate <-90,0,-90> translate <-2.8,3.35,1.75>}
    object {completeclip scale <0.7/3.6,1,0.7/3.6> rotate <90,0,-90> translate <2.8,3.35,1.25>}
    object {Ecore rotate 180*x translate <0,3.7,3>}
  #else
    object {coil translate <0,0.4,1.5>}
    object {PCB translate <0,0.2,1.5>}
    object {completeclip scale <0.7/3.6,1,0.7/3.6> rotate <-90,0,-90> translate <-1.8,0.35,1.75>}
    object {completeclip scale <0.7/3.6,1,0.7/3.6> rotate <90,0,-90> translate <1.8,0.35,1.25>}
    object {Ecore rotate 180*x translate <0,0.7,3>}
  #end
  object {Icore translate <0,0,0>}
  #if(Exploded)  
    rotate <0, -30, 0>
  #else
    rotate <0, -40, 0>
  #end
  finish {
    #if(RAD)  
     ambient 0
      diffuse 0.7 
    #else
      ambient 0.8 
      diffuse 0.5      
    #end   
    phong 1
    phong_size 60
  } 
}
light_source { <0, 14, -10> color White}
light_source { <2, 4, -10> color White}
#if(Exploded)  
  camera {location <1,8,-15> look_at <-0.3,2.2,0> angle 26}
#else
  camera {location <1,10,-15> look_at <-0.6,1,0> angle 17}
#end

then compiled using the following command:

povray -IPlanar_core_assembly_exploded.png -W1280 -H960 -Q11 +A